src/vrpn/cmake/FindDirectX.cmake

-# - try to find part of DirectX SDK
-#
-# Cache Variables: (probably not for direct use in your scripts)
-#  DIRECTX_INCLUDE_DIR
-#
-# Variables you should use in your CMakeLists.txt:
-#  DIRECTX_DXGUID_LIBRARY - deprecated, see below
-#  DIRECTX_DXERR_LIBRARY - deprecated, see http://blogs.msdn.com/b/chuckw/archive/2012/04/24/where-s-dxerr-lib.aspx
-#  DIRECTX_DINPUT_LIBRARY
-#  DIRECTX_DINPUT_INCLUDE_DIR
-#  DIRECTX_D3D9_LIBRARY
-#  DIRECTX_D3DXOF_LIBRARY
-#  DIRECTX_D3DX9_LIBRARIES
-#  DIRECTX_INCLUDE_DIRS
-#  DIRECTX_FOUND - if this is not true, do not attempt to use this library
-#
-# Defines these macros:
-#  find_directx_include - wrapper for find_path that provides PATHS, HINTS, and PATH_SUFFIXES.
-#  find_directx_library - wrapper for find_library that provides PATHS, HINTS, and PATH_SUFFIXES.
-# Requires these CMake modules:
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#  SelectLibraryConfigurations
-#
-# Original Author:
-# 2012 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2012.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-
-set(DIRECTX_ROOT_DIR
-	"${DIRECTX_ROOT_DIR}"
-	CACHE
-	PATH
-	"Root directory to search for DirectX")
-
-if(MSVC)
-	file(TO_CMAKE_PATH "$ENV{ProgramFiles}" _PROG_FILES)
-	file(TO_CMAKE_PATH "$ENV{ProgramFiles(x86)}" _PROG_FILES_X86)
-	if(_PROG_FILES_X86)
-		set(_PROG_FILES "${_PROG_FILES_X86}")
-	endif()
-	if(CMAKE_SIZEOF_VOID_P EQUAL 8)
-		set(_dx_lib_suffixes lib/x64 lib)
-	else()
-		set(_dx_lib_suffixes lib/x86 lib)
-	endif()
-	set(DXSDK_DIRS)
-
-	find_package(WindowsSDK)
-	if(WINDOWSSDK_FOUND)
-		foreach(_dir ${WINDOWSSDK_DIRS})
-			get_windowssdk_include_dirs(${_dir} _include_dirs)
-			if(_include_dirs)
-				list(APPEND DXSDK_DIRS ${_include_dirs})
-			endif()
-		endforeach()
-	endif()
-
-	macro(_append_dxsdk_in_inclusive_range _low _high)
-		if((NOT MSVC_VERSION LESS ${_low}) AND (NOT MSVC_VERSION GREATER ${_high}))
-			list(APPEND DXSDK_DIRS ${ARGN})
-		endif()
-	endmacro()
-	_append_dxsdk_in_inclusive_range(1500 1600 "${_PROG_FILES}/Microsoft DirectX SDK (June 2010)")
-	_append_dxsdk_in_inclusive_range(1400 1600
-		"${_PROG_FILES}/Microsoft DirectX SDK (February 2010)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (August 2009)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (March 2009)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (November 2008)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (August 2008)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (June 2008)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (March 2008)")
-	_append_dxsdk_in_inclusive_range(1310 1500
-		"${_PROG_FILES}/Microsoft DirectX SDK (November 2007)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (August 2007)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (June 2007)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (April 2007)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (February 2007)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (December 2006)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (October 2006)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (August 2006)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (June 2006)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (April 2006)"
-		"${_PROG_FILES}/Microsoft DirectX SDK (February 2006)")
-
-	file(TO_CMAKE_PATH "$ENV{DXSDK_DIR}" ENV_DXSDK_DIR)
-	if(ENV_DXSDK_DIR)
-		list(APPEND DXSDK_DIRS ${ENV_DXSDK_DIR})
-	endif()
-else()
-	set(_dx_lib_suffixes lib)
-	set(DXSDK_DIRS /mingw)
-endif()
-
-find_path(DIRECTX_INCLUDE_DIR
-	NAMES
-	dxdiag.h
-	dinput.h
-	dxerr8.h
-	PATHS
-	${DXSDK_DIRS}
-	HINTS
-	"${DIRECTX_ROOT_DIR}"
-	PATH_SUFFIXES
-	include)
-find_path(DIRECTX_DINPUT_INCLUDE_DIR
-	NAMES
-	dinput.h
-	PATHS
-	${DXSDK_DIRS}
-	HINTS
-	"${DIRECTX_ROOT_DIR}"
-	PATH_SUFFIXES
-	include)
-
-set(DXLIB_HINTS)
-if(WINDOWSSDK_FOUND AND DIRECTX_INCLUDE_DIR)
-	get_windowssdk_from_component("${DIRECTX_INCLUDE_DIR}" _winsdk)
-	if(_winsdk)
-		get_windowssdk_library_dirs("${_winsdk}" _libdirs)
-		if(_libdirs)
-			list(APPEND DXLIB_HINTS ${_libdirs})
-		endif()
-	endif()
-endif()
-
-if(WINDOWSSDK_FOUND AND DIRECTX_DINPUT_INCLUDE_DIR)
-	get_windowssdk_from_component("${DIRECTX_DINPUT_INCLUDE_DIR}" _winsdk)
-	if(_winsdk)
-		get_windowssdk_library_dirs("${_winsdk}" _includes)
-		if(_includes)
-			list(APPEND DXLIB_HINTS ${_includes})
-		endif()
-	endif()
-endif()
-
-find_library(DIRECTX_DXGUID_LIBRARY
-	NAMES
-	dxguid
-	PATHS
-	${DXLIB_HINTS}
-	${DXSDK_DIRS}
-	HINTS
-	"${DIRECTX_ROOT_DIR}"
-	PATH_SUFFIXES
-	${_dx_lib_suffixes})
-
-if(DIRECTX_DXGUID_LIBRARY)
-	get_filename_component(_dxsdk_lib_dir ${DIRECTX_DXGUID_LIBRARY} PATH)
-	list(APPEND DXLIB_HINTS "${_dxsdk_lib_dir}")
-endif()
-
-find_library(DIRECTX_DINPUT_LIBRARY
-	NAMES
-	dinput8
-	dinput
-	PATHS
-	${DXSDK_DIRS}
-	HINTS
-	${DXLIB_HINTS}
-	"${DIRECTX_ROOT_DIR}"
-	PATH_SUFFIXES
-	${_dx_lib_suffixes})
-
-find_library(DIRECTX_DXERR_LIBRARY
-	NAMES
-	dxerr
-	dxerr9
-	dxerr8
-	PATHS
-	${DXSDK_DIRS}
-	HINTS
-	${DXLIB_HINTS}
-	"${DIRECTX_ROOT_DIR}"
-	PATH_SUFFIXES
-	${_dx_lib_suffixes})
-
-find_library(DIRECTX_D3D9_LIBRARY
-	NAMES
-	d3d9
-	PATHS
-	${DXSDK_DIRS}
-	HINTS
-	${DXLIB_HINTS}
-	"${DIRECTX_ROOT_DIR}"
-	PATH_SUFFIXES
-	${_dx_lib_suffixes})
-
-find_library(DIRECTX_D3DXOF_LIBRARY
-	NAMES
-	d3dxof
-	PATHS
-	${DXSDK_DIRS}
-	HINTS
-	${DXLIB_HINTS}
-	"${DIRECTX_ROOT_DIR}"
-	PATH_SUFFIXES
-	${_dx_lib_suffixes})
-
-find_library(DIRECTX_D3DX9_LIBRARY_RELEASE
-	NAMES
-	d3dx9
-	PATHS
-	${DXSDK_DIRS}
-	HINTS
-	${DXLIB_HINTS}
-	"${DIRECTX_ROOT_DIR}"
-	PATH_SUFFIXES
-	${_dx_lib_suffixes})
-
-find_library(DIRECTX_D3DX9_LIBRARY_DEBUG
-	NAMES
-	d3dx9d
-	PATHS
-	${DXSDK_DIRS}
-	HINTS
-	${DXLIB_HINTS}
-	"${DIRECTX_ROOT_DIR}"
-	PATH_SUFFIXES
-	${_dx_lib_suffixes})
-
-find_library(DIRECTX_XINPUT_LIBRARY
-	NAMES
-	Xinput9_1_0
-	Xinput
-	PATHS
-	${DXSDK_DIRS}
-	HINTS
-	${DXLIB_HINTS}
-	"${DIRECTX_ROOT_DIR}"
-	PATH_SUFFIXES
-	${_dx_lib_suffixes})
-
-include(SelectLibraryConfigurations)
-select_library_configurations(DIRECTX_D3DX9)
-
-set(DIRECTX_EXTRA_CHECK)
-if(DIRECTX_INCLUDE_DIR)
-	if(MSVC80)
-		set(DXSDK_DEPRECATION_BUILD 1962)
-	endif()
-
-	if(DXSDK_DEPRECATION_BUILD)
-		include(CheckCSourceCompiles)
-		set(_dinput_old_includes ${CMAKE_REQUIRED_INCLUDES})
-		set(CMAKE_REQUIRED_INCLUDES "${DIRECTX_INCLUDE_DIR}")
-		check_c_source_compiles("
-			#include <dxsdkver.h>
-			#if _DXSDK_BUILD_MAJOR >= ${DXSDK_DEPRECATION_BUILD}
-			#error
-			#else
-			int main(int argc, char * argv[]) {
-				return 0;
-			}
-			#endif
-			"
-			DIRECTX_SDK_SUPPORTS_COMPILER)
-		set(DIRECTX_EXTRA_CHECK DIRECTX_SDK_SUPPORTS_COMPILER)
-		set(CMAKE_REQUIRED_INCLUDES "${_dinput_old_includes}")
-	else()
-		# Until proven otherwise.
-		set(DIRECTX_SDK_SUPPORTS_COMPILER TRUE)
-	endif()
-endif()
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(DirectX
-	DEFAULT_MSG
-	DIRECTX_DXGUID_LIBRARY
-	DIRECTX_DINPUT_LIBRARY
-	DIRECTX_INCLUDE_DIR
-	${DIRECTX_EXTRA_CHECK})
-
-if(DIRECTX_FOUND)
-	set(DIRECTX_LIBRARIES
-		"${DIRECTX_DXGUID_LIBRARY}"
-		"${DIRECTX_DINPUT_LIBRARY}")
-
-	set(DIRECTX_INCLUDE_DIRS "${DIRECTX_INCLUDE_DIR}")
-
-	mark_as_advanced(DIRECTX_ROOT_DIR)
-endif()
-
-macro(find_directx_library)
-	find_library(${ARGN}
-		PATHS
-		${DXSDK_DIRS}
-		HINTS
-		${DXLIB_HINTS}
-		"${DIRECTX_ROOT_DIR}"
-		PATH_SUFFIXES
-		${_dx_lib_suffixes})
-endmacro()
-macro(find_directx_include)
-	find_path(${ARGN}
-		PATHS
-		${DXSDK_DIRS}
-		HINTS
-		${DIRECTX_INCLUDE_DIR}
-		"${DIRECTX_ROOT_DIR}"
-		PATH_SUFFIXES
-		include)
-endmacro()
-
-mark_as_advanced(DIRECTX_DINPUT_LIBRARY
-	DIRECTX_DXGUID_LIBRARY
-	DIRECTX_DXERR_LIBRARY
-	DIRECTX_D3D9_LIBRARY
-	DIRECTX_D3DXOF_LIBRARY
-	DIRECTX_D3DX9_LIBRARY_RELEASE
-	DIRECTX_D3DX9_LIBRARY_DEBUG
-	DIRECTX_INCLUDE_DIR)

src/vrpn/cmake/FindGHOST.cmake

-# - try to find Sensable GHOST library and include files
-#  GHOST_INCLUDE_DIRS, where to find GL/glut.h, etc.
-#  GHOST_LIBRARIES, the libraries to link against
-#  GHOST_FOUND, If false, do not try to use GLUT.
-#  GHOST_RUNTIME_LIBRARY_DIRS, path to DLL on Windows for runtime use.
-#
-# Requires these CMake modules:
-#  no additional modules required
-#
-# Original Author:
-# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2009-2010.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-set(GHOST_ROOT_DIR
-	"${GHOST_ROOT_DIR}"
-	CACHE
-	PATH
-	"Path to search for GHOST")
-
-set(_dirs)
-if(WIN32)
-	include(ProgramFilesGlob)
-	program_files_fallback_glob(_dirs "/Sensable/GHOST/v*/")
-endif()
-
-find_path(GHOST_INCLUDE_DIR
-	gstPHANToM.h
-	PATHS
-	${_dirs}
-	HINTS
-	"${GHOST_ROOT_DIR}"
-	PATH_SUFFIXES
-	include)
-
-find_library(GHOST_LIBRARY
-	GHOST40
-	GHOST31
-	PATHS
-	${_dirs}
-	HINTS
-	"${GHOST_ROOT_DIR}"
-	PATH_SUFFIXES
-	lib)
-
-if(MSVC)
-	if(MSVC_VERSION GREATER 1300)
-		# .NET and newer: fake the STL headers
-		get_filename_component(_moddir "${CMAKE_CURRENT_LIST_FILE}" PATH)
-		set(GHOST_STL_INCLUDE_DIR "${_moddir}/ghost-fake-stl")
-	else()
-		# 6.0 and earlier - use GHOST-provided STL
-		find_path(GHOST_STL_INCLUDE_DIR
-			vector.h
-			PATHS
-			${_dirs}
-			HINTS
-			"${GHOST_ROOT_DIR}"
-			"${GHOST_INCLUDE_DIR}"
-			PATH_SUFFIXES
-			external/stl
-			stl)
-	endif()
-	set(_deps_check GHOST_STL_INCLUDE_DIR)
-else()
-	set(_deps_check)
-endif()
-
-# handle the QUIETLY and REQUIRED arguments and set xxx_FOUND to TRUE if
-# all listed variables are TRUE
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(GHOST
-	DEFAULT_MSG
-	GHOST_LIBRARY
-	${_deps_check}
-	GHOST_INCLUDE_DIR)
-
-if(GHOST_FOUND)
-	set(GHOST_LIBRARIES "${GHOST_LIBRARY}")
-	set(GHOST_INCLUDE_DIRS "${GHOST_INCLUDE_DIR}")
-
-	mark_as_advanced(GHOST_ROOT_DIR)
-endif()
-
-mark_as_advanced(GHOST_LIBRARY GHOST_STL_INCLUDE_DIR GHOST_INCLUDE_DIR)

src/vrpn/cmake/FindGPM.cmake

-# - try to find GPM library
-#
-# Cache Variables: (probably not for direct use in your scripts)
-#  GPM_INCLUDE_DIR
-#  GPM_LIBRARY
-#
-# Non-cache variables you might use in your CMakeLists.txt:
-#  GPM_FOUND
-#  GPM_INCLUDE_DIRS
-#  GPM_LIBRARIES
-#
-# Requires these CMake modules:
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#
-# Original Author:
-# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2009-2010.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-find_library(GPM_LIBRARY
-	NAMES gpm)
-
-find_path(GPM_INCLUDE_DIR
-	NAMES gpm.h)
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(GPM
-	DEFAULT_MSG
-	GPM_LIBRARY
-	GPM_INCLUDE_DIR)
-
-if(GPM_FOUND)
-	set(GPM_LIBRARIES "${GPM_LIBRARY}")
-
-	set(GPM_INCLUDE_DIRS "${GPM_INCLUDE_DIR}")
-endif()
-
-mark_as_advanced(GPM_INCLUDE_DIR GPM_LIBRARY)

src/vrpn/cmake/FindHIDAPI.cmake

-# - try to find HIDAPI library
-# from http://www.signal11.us/oss/hidapi/
-#
-# Cache Variables: (probably not for direct use in your scripts)
-#  HIDAPI_INCLUDE_DIR
-#  HIDAPI_LIBRARY
-#
-# Non-cache variables you might use in your CMakeLists.txt:
-#  HIDAPI_FOUND
-#  HIDAPI_INCLUDE_DIRS
-#  HIDAPI_LIBRARIES
-#
-# Requires these CMake modules:
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#
-# Original Author:
-# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2009-2010.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-find_library(HIDAPI_LIBRARY
-	NAMES hidapi)
-
-find_path(HIDAPI_INCLUDE_DIR
-	NAMES hidapi.h)
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(HIDAPI
-	DEFAULT_MSG
-	HIDAPI_LIBRARY
-	HIDAPI_INCLUDE_DIR)
-
-if(HIDAPI_FOUND)
-	set(HIDAPI_LIBRARIES "${HIDAPI_LIBRARY}")
-
-	set(HIDAPI_INCLUDE_DIRS "${HIDAPI_INCLUDE_DIR}")
-endif()
-
-mark_as_advanced(HIDAPI_INCLUDE_DIR HIDAPI_LIBRARY)

src/vrpn/cmake/FindInterSense.cmake

-# - try to find InterSense library
-#
-# Cache Variables: (probably not for direct use in your scripts)
-#  INTERSENSE_INCLUDE_DIR
-#  INTERSENSE_ISENSEC_DIR - location of the isense.c "import library" substitute.
-#  INTERSENSE_LIBRARY
-#
-# Non-cache variables you might use in your CMakeLists.txt:
-#  INTERSENSE_FOUND
-#  INTERSENSE_INCLUDE_DIRS
-#  INTERSENSE_LIBRARIES
-#
-# Requires these CMake modules:
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#
-# Author:
-# 2013 Eric Marsh <bits@wemarsh.com>
-# http://wemarsh.com/
-# Kognitiv Neuroinformatik, Universität Bremen
-#
-# (building on Ryan Pavlik's templates)
-#
-# 2013 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-set(INTERSENSE_ROOT_DIR
-	"${INTERSENSE_ROOT_DIR}"
-	CACHE
-	PATH
-	"Directory to search for the Intersense SDK")
-
-if(APPLE)
-	set(_ARCH UniversalLib)
-else()
-	if(CMAKE_SIZEOF_VOID_P MATCHES "8")
-		set(_ARCH x86_64)
-	else()
-		set(_ARCH x86_32)
-	endif()
-endif()
-
-if(APPLE)
-	set(_SDKDIR MacOSX)
-elseif(WIN32)
-	set(_SDKDIR Windows)
-else() # Assume Linux, since that's the only other platform supported by this library
-	set(_SDKDIR Linux)
-endif()
-
-find_path(INTERSENSE_INCLUDE_DIR
-	NAMES isense.h
-	PATHS "${INTERSENSE_ROOT_DIR}" "${INTERSENSE_ROOT_DIR}/SDK")
-
-find_path(INTERSENSE_ISENSEC_DIR
-	NAMES isense.c
-	PATHS "${INTERSENSE_ROOT_DIR}" "${INTERSENSE_ROOT_DIR}/SDK"
-	PATH_SUFFIXES
-	Linux/Sample
-	MacOSX/Sample
-	"Windows/Sample/Visual C++ 2005"
-	"Windows/Sample/Visual C++ 2005 (single tracker)")
-
-include(FindPackageHandleStandardArgs)
-
-# This is a weird one - no import library is supplied, and instead, at least on Windows, they use
-# an isense.c file to call into the DLL. Not sure if MinGW can link right against the dll in this case.
-if(WIN32)
-	find_package_handle_standard_args(InterSense
-		DEFAULT_MSG
-		INTERSENSE_INCLUDE_DIR
-		INTERSENSE_ISENSEC_DIR)
-	if(INTERSENSE_FOUND)
-		set(INTERSENSE_LIBRARIES "")
-		set(INTERSENSE_INCLUDE_DIRS "${INTERSENSE_INCLUDE_DIR}" "${INTERSENSE_ISENSEC_DIR}")
-	endif()
-else() # Only MSVC on Windows theoretically needs import libraries, so...
-	find_library(INTERSENSE_LIBRARY
-		NAMES isense
-		PATHS "${INTERSENSE_ROOT_DIR}" "${INTERSENSE_ROOT_DIR}/SDK"
-		PATH_SUFFIXES "${_SDKDIR}/${_ARCH}")
-
-	find_package_handle_standard_args(InterSense
-		DEFAULT_MSG
-		INTERSENSE_LIBRARY
-		INTERSENSE_INCLUDE_DIR)
-
-	if(INTERSENSE_FOUND)
-		set(INTERSENSE_LIBRARIES "${INTERSENSE_LIBRARY}" ${CMAKE_DL_LIBS})
-		set(INTERSENSE_INCLUDE_DIRS "${INTERSENSE_INCLUDE_DIR}")
-	endif()
-endif()
-
-mark_as_advanced(INTERSENSE_INCLUDE_DIR INTERSENSE_ISENSEC_DIR INTERSENSE_LIBRARY)

src/vrpn/cmake/FindJsonCpp.cmake

-# - try to find JSONCPP library
-#
-# Cache Variables: (probably not for direct use in your scripts)
-#  JSONCPP_INCLUDE_DIR
-#  JSONCPP_LIBRARY
-#
-# Non-cache variables you might use in your CMakeLists.txt:
-#  JSONCPP_FOUND
-#  JSONCPP_INCLUDE_DIRS
-#  JSONCPP_LIBRARIES
-#
-# Requires these CMake modules:
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#
-# Author:
-# 2011 Philippe Crassous (ENSAM ParisTech / Institut Image) p.crassous _at_ free.fr
-
-
-set(JSONCPP_ROOT_DIR
-	"${JSONCPP_ROOT_DIR}"
-	CACHE
-	PATH
-	"Directory to search for JSONCPP")
-set(_jsoncppnames)
-set(_pathsuffixes
-	suncc
-	vacpp
-	mingw
-	msvc6
-	msvc7
-	msvc71
-	msvc80
-	msvc90
-	linux-gcc)
-if(CMAKE_COMPILER_IS_GNUCXX)
-	execute_process(COMMAND
-		${CMAKE_CXX_COMPILER}
-		-dumpversion
-		OUTPUT_VARIABLE
-		_gnucxx_ver
-		OUTPUT_STRIP_TRAILING_WHITESPACE)
-	list(APPEND
-		_jsoncppnames
-		json_linux-gcc-${_gnucxx_ver}_libmt
-		json_linux-gcc_libmt)
-	list(APPEND _pathsuffixes linux-gcc-${_gnucxx_ver})
-elseif(MSVC)
-	if(MSVC_VERSION EQUAL 1200)
-		list(APPEND _jsoncppnames json_vc6_libmt)
-	elseif(MSVC_VERSION EQUAL 1300)
-		list(APPEND _jsoncppnames json_vc7_libmt)
-	elseif(MSVC_VERSION EQUAL 1310)
-		list(APPEND _jsoncppnames json_vc71_libmt)
-	elseif(MSVC_VERSION EQUAL 1400)
-		list(APPEND _jsoncppnames json_vc8_libmt)
-	elseif(MSVC_VERSION EQUAL 1500)
-		list(APPEND _jsoncppnames json_vc9_libmt)
-	elseif(MSVC_VERSION EQUAL 1600)
-		list(APPEND _jsoncppnames json_vc10_libmt)
-	endif()
-else()
-	list(APPEND _jsoncppnames
-		json_suncc_libmt
-		json_vacpp_libmt)
-endif()
-
-list(APPEND _jsoncppnames
-	json_mingw_libmt)
-
-find_library(JSONCPP_LIBRARY
-	NAMES
-	${_jsoncppnames}
-	PATHS
-	"${JSONCPP_ROOT_DIR}/libs"
-	PATH_SUFFIXES
-	${_pathsuffixes})
-
-find_path(JSONCPP_INCLUDE_DIR
-	NAMES
-	json/json.h
-	PATHS
-	"${JSONCPP_ROOT_DIR}"
-	PATH_SUFFIXES
-	include)
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(JSONCPP
-	DEFAULT_MSG
-	JSONCPP_LIBRARY
-	JSONCPP_INCLUDE_DIR)
-
-if(JSONCPP_FOUND)
-	set(JSONCPP_LIBRARIES "${JSONCPP_LIBRARY}")
-	set(JSONCPP_INCLUDE_DIRS "${JSONCPP_INCLUDE_DIR}")
-	mark_as_advanced(JSONCPP_ROOT_DIR)
-endif()
-
-mark_as_advanced(JSONCPP_INCLUDE_DIR JSONCPP_LIBRARY)

src/vrpn/cmake/FindLibFreespace.cmake

-# - try to find Hillcrest Labs' libfreespace library
-#
-# Cache Variables: (probably not for direct use in your scripts)
-#  LIBFREESPACE_INCLUDE_DIR
-#  LIBFREESPACE_LIBRARY
-#
-# Non-cache variables you might use in your CMakeLists.txt:
-#  LIBFREESPACE_FOUND
-#  LIBFREESPACE_INCLUDE_DIRS
-#  LIBFREESPACE_LIBRARIES
-#
-# Requires these CMake modules:
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#
-# Original Author:
-# 2014 Ryan Pavlik <ryan@sensics.com> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-#
-# Copyright Sensics 2014.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-set(LIBFREESPACE_ROOT_DIR
-	"${LIBFREESPACE_ROOT_DIR}"
-	CACHE
-	PATH
-	"Directory to search for libfreespace")
-
-find_library(LIBFREESPACE_LIBRARY
-	NAMES
-	freespace
-	libfreespace
-	PATHS
-	"${LIBFREESPACE_ROOT_DIR}"
-	PATH_SUFFIXES
-	lib)
-
-get_filename_component(_libdir "${LIBFREESPACE_LIBRARY}" PATH)
-
-find_path(LIBFREESPACE_INCLUDE_DIR
-	NAMES
-	freespace/freespace.h
-	HINTS
-	"${_libdir}"
-	"${_libdir}/.."
-	PATHS
-	"${LIBFREESPACE_ROOT_DIR}"
-	PATH_SUFFIXES
-	include/)
-
-
-include(FindPackageHandleStandardArgs)
-if(WIN32)
-	find_package(WinHID QUIET)
-	find_package_handle_standard_args(LibFreespace
-		DEFAULT_MSG
-		LIBFREESPACE_LIBRARY
-		LIBFREESPACE_INCLUDE_DIR
-		WINHID_LIBRARIES)
-else()
-	find_package_handle_standard_args(LibFreespace
-		DEFAULT_MSG
-		LIBFREESPACE_LIBRARY
-		LIBFREESPACE_INCLUDE_DIR)
-endif()
-
-if(LIBFREESPACE_FOUND)
-	set(LIBFREESPACE_LIBRARIES "${LIBFREESPACE_LIBRARY}")
-	if(WIN32)
-		list(APPEND LIBFREESPACE_LIBRARIES ${WINHID_LIBRARIES})
-	endif()
-	set(LIBFREESPACE_INCLUDE_DIRS "${LIBFREESPACE_INCLUDE_DIR}")
-	mark_as_advanced(LIBFREESPACE_ROOT_DIR)
-endif()
-
-mark_as_advanced(LIBFREESPACE_INCLUDE_DIR
-	LIBFREESPACE_LIBRARY)

src/vrpn/cmake/FindLibNifalcon.cmake

-# - try to find Libnifalcon library
-#
-#
-# Cache Variables: (probably not for direct use in your scripts)
-#  LIBNIFALCON_ROOT_DIR - where to start searching
-#  LIBNIFALCON_INCLUDE_DIR
-#  LIBNIFALCON_LIBRARY
-#  LIBNIFALCON_LIBUSB1_LIBRARY - Unix only
-#  LIBNIFALCON_LIBUSB1_INCLUDE_DIR - Unix only
-#  LIBNIFALCON_rt_LIBRARY - Unix only
-#
-# Non-cache variables you might use in your CMakeLists.txt:
-#  LIBNIFALCON_FOUND
-#  LIBNIFALCON_INCLUDE_DIRS
-#  LIBNIFALCON_LIBRARIES
-#
-# Requires these CMake modules:
-#  FindPackageHandleStandardArgs (known to be included with CMake >=2.6.2)
-#
-# 2010 Axel Kohlmeyer, <akohlmey@gmail.com>
-
-set(LIBNIFALCON_ROOT_DIR
-	"${LIBNIFALCON_ROOT_DIR}"
-	CACHE
-	PATH
-	"Where to start searching")
-
-find_library(LIBNIFALCON_LIBRARY
-	NAMES
-	libnifalcon
-	nifalcon
-	HINTS
-	"${LIBNIFALCON_ROOT_DIR}"
-	PATH_SUFFIXES
-	include)
-
-get_filename_component(_libdir "${LIBNIFALCON_LIBRARY}" PATH)
-
-find_path(LIBNIFALCON_INCLUDE_DIR
-	NAMES
-	falcon/core/FalconDevice.h
-	HINTS
-	"${_libdir}")
-
-set(_deps_check)
-if(NOT WIN32)
-	find_library(LIBNIFALCON_LIBUSB1_LIBRARY NAMES libusb-1.0 usb-1.0)
-	get_filename_component(_libdir "${LIBNIFALCON_LIBUSB1_LIBRARY}" PATH)
-
-	find_path(LIBNIFALCON_LIBUSB1_INCLUDE_DIR
-		NAMES
-		libusb-1.0/libusb.h
-		HINTS
-		"${_libdir}")
-
-	find_library(LIBNIFALCON_rt_LIBRARY NAMES rt)
-	set(_deps_check
-		LIBNIFALCON_LIBUSB1_LIBRARY
-		LIBNIFALCON_LIBUSB1_INCLUDE_DIR
-		LIBNIFALCON_rt_LIBRARY)
-endif()
-
-find_package(Boost QUIET)
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(libnifalcon
-	DEFAULT_MSG
-	LIBNIFALCON_LIBRARY
-	LIBNIFALCON_INCLUDE_DIR
-	Boost_INCLUDE_DIR
-	${_deps_check})
-
-if(LIBNIFALCON_FOUND)
-	set(LIBNIFALCON_LIBRARIES "${LIBNIFALCON_LIBRARY}")
-	set(LIBNIFALCON_LIBRARY_DIRS "${_libdir}")
-	set(LIBNIFALCON_INCLUDE_DIRS "${LIBNIFALCON_INCLUDE_DIR}" "${Boost_INCLUDE_DIR}")
-
-	if(NOT WIN32)
-		list(APPEND
-			LIBNIFALCON_LIBRARIES
-			"${LIBNIFALCON_LIBUSB1_LIBRARY}"
-			"${LIBNIFALCON_rt_LIBRARY}")
-		list(APPEND
-			LIBNIFALCON_INCLUDE_DIRS
-			"${LIBNIFALCON_LIBUSB1_INCLUDE_DIR}")
-	endif()
-
-	mark_as_advanced(LIBNIFALCON_ROOT_DIR)
-endif()
-
-mark_as_advanced(LIBNIFALCON_INCLUDE_DIR
-	LIBNIFALCON_LIBRARY
-	LIBNIFALCON_LIBUSB1_LIBRARY
-	LIBNIFALCON_LIBUSB1_INCLUDE_DIR
-	LIBNIFALCON_rt_LIBRARY)

src/vrpn/cmake/FindLibusb1.cmake

-# - try to find libusb-1 library
-#
-# Cache Variables: (probably not for direct use in your scripts)
-#  LIBUSB1_LIBRARY
-#  LIBUSB1_INCLUDE_DIR
-#
-# Non-cache variables you should use in your CMakeLists.txt:
-#  LIBUSB1_LIBRARIES
-#  LIBUSB1_INCLUDE_DIRS
-#  LIBUSB1_FOUND - if this is not true, do not attempt to use this library
-#
-# Requires these CMake modules:
-#  ProgramFilesGlob
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#
-# Original Author:
-# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2009-2010.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-
-set(LIBUSB1_ROOT_DIR
-	"${LIBUSB1_ROOT_DIR}"
-	CACHE
-	PATH
-	"Root directory to search for libusb-1")
-
-if(WIN32)
-	include(ProgramFilesGlob)
-	program_files_fallback_glob(_dirs "LibUSB-Win32")
-	if(CMAKE_SIZEOF_VOID_P EQUAL 8)
-		if(MSVC)
-			set(_lib_suffixes lib/msvc_x64)
-		endif()
-	else()
-		if(MSVC)
-			set(_lib_suffixes lib/msvc)
-		elseif(COMPILER_IS_GNUCXX)
-			set(_lib_suffixes lib/gcc)
-		endif()
-	endif()
-else()
-	set(_lib_suffixes)
-	find_package(PkgConfig QUIET)
-	if(PKG_CONFIG_FOUND)
-		pkg_check_modules(PC_LIBUSB1 libusb-1.0)
-	endif()
-endif()
-
-find_path(LIBUSB1_INCLUDE_DIR
-	NAMES
-	libusb.h
-	PATHS
-	${PC_LIBUSB1_INCLUDE_DIRS}
-	${PC_LIBUSB1_INCLUDEDIR}
-	${_dirs}
-	HINTS
-	"${LIBUSB1_ROOT_DIR}"
-	PATH_SUFFIXES
-	include
-	libusb-1.0)
-
-find_library(LIBUSB1_LIBRARY
-	NAMES
-	usb-1.0
-	PATHS
-	${PC_LIBUSB1_LIBRARY_DIRS}
-	${PC_LIBUSB1_LIBDIR}
-	${_dirs}
-	PATH_SUFFIXES
-	${_lib_suffixes})
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(Libusb1
-	DEFAULT_MSG
-	LIBUSB1_LIBRARY
-	LIBUSB1_INCLUDE_DIR)
-
-if(LIBUSB1_FOUND)
-	set(LIBUSB1_LIBRARIES "${LIBUSB1_LIBRARY}")
-
-	set(LIBUSB1_INCLUDE_DIRS "${LIBUSB1_INCLUDE_DIR}")
-
-	mark_as_advanced(LIBUSB1_ROOT_DIR)
-endif()
-
-mark_as_advanced(LIBUSB1_INCLUDE_DIR LIBUSB1_LIBRARY)

src/vrpn/cmake/FindMacHID.cmake

-# - try to find Mac HID frameworks
-#
-# Cache Variables: (probably not for direct use in your scripts)
-#  MACHID_CoreFoundation_LIBRARY
-#  MACHID_CoreFoundation_INCLUDE_DIR
-#  MACHID_IOKit_LIBRARY
-#  MACHID_IOKit_INCLUDE_DIR
-#  MACOSX_HID_UINT32T  (from CheckMacHIDAPI)
-#
-# Non-cache variables you should use in your CMakeLists.txt:
-#  MACHID_DEFINITIONS
-#  MACHID_LIBRARIES
-#  MACHID_INCLUDE_DIRS
-#  MACHID_FOUND - if this is not true, do not attempt to use this library
-#
-# Requires these CMake modules:
-#  CheckMacHIDAPI
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#
-# Original Author:
-# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2009-2010.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-if(APPLE)
-	find_library(MACHID_CoreFoundation_LIBRARY CoreFoundation)
-	find_path(MACHID_CoreFoundation_INCLUDE_DIR
-		CoreFoundation/CoreFoundation.h)
-
-	find_library(MACHID_IOKit_LIBRARY IOKit)
-	find_path(MACHID_IOKit_INCLUDE_DIR IOKit/hid/IOHIDLib.h)
-
-	include(CheckMacHIDAPI)
-	set(MACHID_DEFINITIONS "-DMACOSX_HID_UINT32T=${MACOSX_HID_UINT32T}")
-
-	include(FindPackageHandleStandardArgs)
-	find_package_handle_standard_args(MacHID
-		DEFAULT_MSG
-		MACHID_CoreFoundation_LIBRARY
-		MACHID_CoreFoundation_INCLUDE_DIR
-		MACHID_IOKit_LIBRARY
-		MACHID_IOKit_INCLUDE_DIR
-		MACOSX_HID_UINT32T)
-
-endif()
-
-if(MACHID_FOUND)
-	set(MACHID_LIBRARIES
-		"${MACHID_CoreFoundation_LIBRARY}"
-		"${MACHID_IOKit_LIBRARY}")
-
-	set(MACHID_INCLUDE_DIRS
-		"${MACHID_CoreFoundation_INCLUDE_DIR}"
-		"${MACHID_IOKit_INCLUDE_DIR}")
-
-	mark_as_advanced(MACHID_CoreFoundation_LIBRARY
-		MACHID_CoreFoundation_INCLUDE_DIR
-		MACHID_IOKit_LIBRARY
-		MACHID_IOKit_INCLUDE_DIR)
-
-endif()

src/vrpn/cmake/FindModbus.cmake

-# - Find Modbus library
-# Find the Modbus headers and libraries.
-#
-#  MODBUS_INCLUDE_DIRS - where to find modbus.h
-#  MODBUS_LIBRARIES    - List of libraries when using modbus.
-#  MODBUS_FOUND        - True if modbus library found.
-#
-
-# Based on Findquatlib.cmake, Original Author:
-# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2009-2010.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-set(MODBUS_ROOT_DIR
-	"${MODBUS_ROOT_DIR}"
-	CACHE
-	PATH
-	"Root directory to search for libmodbus")
-
-if("${CMAKE_SIZEOF_VOID_P}" MATCHES "8")
-	set(_libsuffixes lib64 lib)
-
-	# 64-bit dir: only set on win64
-	file(TO_CMAKE_PATH "$ENV{ProgramW6432}" _progfiles)
-else()
-	set(_libsuffixes lib)
-	if(NOT "$ENV{ProgramFiles(x86)}" STREQUAL "")
-		# 32-bit dir: only set on win64
-		file(TO_CMAKE_PATH "$ENV{ProgramFiles(x86)}" _progfiles)
-	else()
-		# 32-bit dir on win32, useless to us on win64
-		file(TO_CMAKE_PATH "$ENV{ProgramFiles}" _progfiles)
-	endif()
-endif()
-
-# Look for the header file.
-find_path(MODBUS_INCLUDE_DIR
-	NAMES
-	modbus.h
-	HINTS
-	"${MODBUS_ROOT_DIR}"
-	PATH_SUFFIXES
-	include
-	PATHS
-	"${_progfiles}/libmodbus"
-	C:/usr/local
-	/usr/local)
-
-# Look for the library.
-find_library(MODBUS_LIBRARY
-	NAMES
-	libmodbus.lib
-	libmodbus.a
-	HINTS
-	"${MODBUS_ROOT_DIR}"
-	PATH_SUFFIXES
-	${_libsuffixes}
-	PATHS
-	"${_progfiles}/libmodbus"
-	C:/usr/local
-	/usr/local)
-
-# handle the QUIETLY and REQUIRED arguments and set MODBUS_FOUND to TRUE if
-# all listed variables are TRUE
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(Modbus
-	DEFAULT_MSG
-	MODBUS_LIBRARY
-	MODBUS_INCLUDE_DIR)
-
-if(MODBUS_FOUND)
-	set(MODBUS_LIBRARIES ${MODBUS_LIBRARY})
-	set(MODBUS_INCLUDE_DIRS ${MODBUS_INCLUDE_DIR})
-
-	mark_as_advanced(MODBUS_ROOT_DIR)
-else()
-	set(MODBUS_LIBRARIES)
-	set(MODBUS_INCLUDE_DIRS)
-endif()
-
-mark_as_advanced(MODBUS_LIBRARY MODBUS_INCLUDE_DIR)
-

src/vrpn/cmake/FindNIDAQmx.cmake

-# - try to find NIDAQMX library
-#
-# Cache Variables: (probably not for direct use in your scripts)
-#  NIDAQMX_INCLUDE_DIR
-#  NIDAQMX_LIBRARY
-#
-# Non-cache variables you might use in your CMakeLists.txt:
-#  NIDAQMX_FOUND
-#  NIDAQMX_INCLUDE_DIRS
-#  NIDAQMX_LIBRARIES
-#
-# Requires these CMake modules:
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#
-# Original Author:
-# 2011 Russell M. Taylor II <taylorr@cs.unc.edu>
-
-# Copyright University of North Carolina at Chapel Hill 2011
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-find_library(NIDAQMX_LIBRARY
-	NAMES
-	NIDAQmx
-	PATHS
-	"C:/Program Files (x86)/National Instruments/NI-DAQ/DAQmx ANSI C Dev/lib/msvc")
-
-find_path(NIDAQMX_INCLUDE_DIR
-	NAMES
-	NIDAQmx.h
-	PATHS
-	"C:/Program Files (x86)/National Instruments/NI-DAQ/DAQmx ANSI C Dev/include")
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(NIDAQmx
-	DEFAULT_MSG
-	NIDAQMX_LIBRARY
-	NIDAQMX_INCLUDE_DIR)
-
-if(NIDAQMX_FOUND)
-	set(NIDAQMX_LIBRARIES "${NIDAQMX_LIBRARY}")
-
-	set(NIDAQMX_INCLUDE_DIRS "${NIDAQMX_INCLUDE_DIR}")
-endif()
-
-mark_as_advanced(NIDAQMX_INCLUDE_DIR NIDAQMX_LIBRARY)
-

src/vrpn/cmake/FindOpenHaptics.cmake

-# - try to find OpenHaptics libraries
-#
-# Cache Variables: (probably not for direct use in your scripts)
-#  HDAPI_INCLUDE_DIR
-#  HDAPI_LIBRARY
-#  HDAPI_LIBRARY_RELEASE
-#  HDAPI_LIBRARY_DEBUG
-#  HDAPI_HDU_INCLUDE_DIR
-#  HDAPI_HDU_LIBRARY
-#  HDAPI_HDU_LIBRARY_RELEASE
-#  HDAPI_HDU_LIBRARY_DEBUG
-#  HLAPI_INCLUDE_DIR
-#  HLAPI_LIBRARY
-#  HLAPI_LIBRARY_RELEASE
-#  HLAPI_LIBRARY_DEBUG
-#  HLAPI_HLU_INCLUDE_DIR
-#  HLAPI_HLU_LIBRARY
-#  HLAPI_HLU_LIBRARY_RELEASE
-#  HLAPI_HLU_LIBRARY_DEBUG
-#
-# Non-cache variables you might use in your CMakeLists.txt:
-#  OPENHAPTICS_FOUND
-#  HDAPI_INCLUDE_DIRS
-#  HDAPI_LIBRARIES
-#  HDAPI_HDU_INCLUDE_DIRS
-#  HDAPI_HDU_LIBRARIES
-#  HLAPI_INCLUDE_DIRS
-#  HLAPI_LIBRARIES
-#  HLAPI_HLU_INCLUDE_DIRS
-#  HLAPI_HLU_LIBRARIES
-#  OPENHAPTICS_LIBRARIES - includes HD, HDU, HL, HLU
-#  OPENHAPTICS_RUNTIME_LIBRARY_DIRS
-#  OPENHAPTICS_ENVIRONMENT
-#  OPENHAPTICS_LIBRARY_DIRS
-#  OPENHAPTICS_INCLUDE_DIRS
-#
-# Requires these CMake modules:
-#  CleanDirectoryList
-#  CleanLibraryList
-#  ListCombinations
-#  ProgramFilesGlob
-#  SelectLibraryConfigurations (included with CMake >=2.8.0)
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#  CMake 2.6.3 (uses "unset")
-#
-# Original Author:
-# 2009-2012 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2009-2010.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-cmake_minimum_required(VERSION 2.6.3)
-
-set(OPENHAPTICS_ROOT_DIR
-	"${OPENHAPTICS_ROOT_DIR}"
-	CACHE
-	PATH
-	"Path to search for OpenHaptics")
-option(OPENHAPTICS_NESTED_TARGETS
-	"Whether we should compile HDU and HLU, if needed, as a part of the solution"
-	ON)
-mark_as_advanced(OPENHAPTICS_NESTED_TARGETS)
-
-###
-# Configure OpenHaptics
-###
-
-include(SelectLibraryConfigurations)
-include(ListCombinations)
-include(CleanDirectoryList)
-include(CleanLibraryList)
-include(ProgramFilesGlob)
-
-set(_nest_targets)
-set(_incsearchdirs)
-set(_libsearchdirs)
-set(OPENHAPTICS_ENVIRONMENT)
-set(OPENHAPTICS_RUNTIME_LIBRARY_DIRS)
-
-set(_dirs)
-if(NOT "$ENV{OH_SDK_BASE}" STREQUAL "")
-	list(APPEND _dirs "$ENV{OH_SDK_BASE}")
-elseif(NOT "$ENV{3DTOUCH_BASE}" STREQUAL "")
-	list(APPEND _dirs "$ENV{3DTOUCH_BASE}")
-endif()
-if(WIN32)
-	program_files_fallback_glob(_pfdirs "/Sensable/3DTouch*/")
-	foreach(_OH_DEFAULT_LOCATION "C:/OpenHaptics/3.1" "C:/OpenHaptics/Academic/3.1")
-		if(EXISTS "${_OH_DEFAULT_LOCATION}")
-			list(APPEND _dirs "${_OH_DEFAULT_LOCATION}")
-		endif()
-	endforeach()
-	set(_dirs "${_dirs};${_pfdirs}")
-	if(MSVC60)
-		set(_vc "vc6")
-	elseif(MSVC70 OR MSVC71)
-		set(_vc "vc7")
-	elseif(MSVC80)
-		set(_vc "vc8")
-	endif()
-	if(CMAKE_SIZEOF_VOID_P MATCHES "8")
-		# 64-bit
-		list_combinations(_libsearch
-			PREFIXES
-			"${OPENHAPTICS_ROOT_DIR}"
-			${_dirs}
-			SUFFIXES
-			"/lib/x64")
-		list_combinations(_libsearch2
-			PREFIXES
-			"${OPENHAPTICS_ROOT_DIR}"
-			${_dirs}
-			SUFFIXES
-			"/utilities/lib/x64")
-	else()
-		# 32-bit
-		list_combinations(_libsearch
-			PREFIXES
-			"${OPENHAPTICS_ROOT_DIR}"
-			${_dirs}
-			SUFFIXES
-			"/lib"
-			"/lib/win32")
-		list_combinations(_libsearch2
-			PREFIXES
-			"${OPENHAPTICS_ROOT_DIR}"
-			${_dirs}
-			SUFFIXES
-			"/utilities/lib/Win32"
-			"/utilities/lib"
-			"/utilities/lib/${_vc}")
-	endif()
-
-	clean_directory_list(_libsearchdirs ${_libsearch} ${_libsearch2})
-endif()
-
-list_combinations(_incsearch
-	PREFIXES
-	"${OPENHAPTICS_ROOT_DIR}"
-	${_dirs}
-	SUFFIXES
-	"/include")
-list_combinations(_incsearch2
-	PREFIXES
-	"${OPENHAPTICS_ROOT_DIR}"
-	${_dirs}
-	SUFFIXES
-	"/utilities/include")
-clean_directory_list(_incsearchdirs ${_incsearch} ${_incsearch2})
-
-set(_deps_check)
-set(_deps_libs)
-
-###
-# HDAPI: HD
-###
-
-if(UNIX)
-	find_library(HDAPI_PHANToMIO_LIBRARY
-		NAMES
-		PHANToMIO
-		HINTS
-		${_libsearchdirs})
-	mark_as_advanced(HDAPI_PHANToMIO_LIBRARY)
-	list(APPEND _deps_check HDAPI_PHANToMIO_LIBRARY)
-	list(APPEND _deps_libs "${HDAPI_PHANToMIO_LIBRARY}")
-endif()
-
-find_path(HDAPI_INCLUDE_DIR
-	NAMES
-	HD/hd.h
-	HINTS
-	${_incsearchdirs})
-
-find_library(HDAPI_LIBRARY_RELEASE
-	NAMES
-	HD
-	PATH_SUFFIXES
-	ReleaseAcademicEdition
-	Release
-	HINTS
-	${_libsearchdirs})
-
-find_library(HDAPI_LIBRARY_DEBUG
-	NAMES
-	HD
-	PATH_SUFFIXES
-	DebugAcademicEdition
-	Debug
-	HINTS
-	${_libsearchdirs})
-
-select_library_configurations(HDAPI)
-
-###
-# HDAPI: HDU
-###
-find_path(HDAPI_HDU_INCLUDE_DIR
-	NAMES
-	HDU/hdu.h
-	HINTS
-	${_incsearchdirs})
-
-find_library(HDAPI_HDU_LIBRARY_RELEASE
-	NAMES
-	HDU
-	PATH_SUFFIXES
-	ReleaseAcademicEdition
-	Release
-	HINTS
-	${_libsearchdirs})
-
-find_library(HDAPI_HDU_LIBRARY_DEBUG
-	NAMES
-	HDU
-	PATH_SUFFIXES
-	DebugAcademicEdition
-	Debug
-	HINTS
-	${_libsearchdirs})
-
-# Fallback
-find_library(HDAPI_HDU_LIBRARY_DEBUG
-	NAMES
-	HDUD
-	PATH_SUFFIXES
-	DebugAcademicEdition
-	Debug
-	HINTS
-	${_libsearchdirs})
-
-select_library_configurations(HDAPI_HDU)
-
-if(OPENHAPTICS_NESTED_TARGETS OR NOT HDAPI_HDU_LIBRARY)
-	if(HDAPI_HDU_SOURCE_DIR AND NOT EXISTS "${HDAPI_HDU_SOURCE_DIR}/hdu.cpp")
-		unset(HDAPI_HDU_SOURCE_DIR)
-	endif()
-	find_path(HDAPI_HDU_SOURCE_DIR
-		NAMES
-		hdu.cpp
-		PATH_SUFFIXES
-		src
-		src/HDU
-		src/HDU/src
-		libsrc/HDU
-		HINTS
-		"${HDAPI_HDU_INCLUDE_DIR}/.."
-		"${HDAPI_HDU_INCLUDE_DIR}/../share/3DTouch")
-	list(APPEND _deps_check HDAPI_HDU_SOURCE_DIR)
-	if(HDAPI_HDU_SOURCE_DIR)
-		mark_as_advanced(HDAPI_HDU_SOURCE_DIR)
-		set(_nest_targets YES)
-		set(HDAPI_HDU_LIBRARY
-			"openhaptics_hdu_nested_target"
-			CACHE
-			STRING
-			"We will build the OpenHaptics HDU lib."
-			FORCE)
-		set(HDAPI_HDU_LIBRARIES ${HDAPI_HDU_LIBRARY})
-	endif()
-endif()
-
-
-###
-# HLAPI: HL
-###
-find_path(HLAPI_INCLUDE_DIR
-	NAMES
-	HL/hl.h
-	HINTS
-	${_incsearchdirs})
-
-find_library(HLAPI_LIBRARY_RELEASE
-	NAMES
-	HL
-	PATH_SUFFIXES
-	ReleaseAcademicEdition
-	Release
-	HINTS
-	${_libsearchdirs})
-
-find_library(HLAPI_LIBRARY_DEBUG
-	NAMES
-	HL
-	PATH_SUFFIXES
-	DebugAcademicEdition
-	Debug
-	HINTS
-	${_libsearchdirs})
-
-select_library_configurations(HLAPI)
-
-###
-# HLAPI: HLU
-###
-find_path(HLAPI_HLU_INCLUDE_DIR
-	NAMES
-	HLU/hlu.h
-	HINTS
-	${_incsearchdirs})
-
-find_library(HLAPI_HLU_LIBRARY_RELEASE
-	NAMES
-	HLU
-	PATH_SUFFIXES
-	ReleaseAcademicEdition
-	Release
-	HINTS
-	${_libsearchdirs})
-
-find_library(HLAPI_HLU_LIBRARY_DEBUG
-	NAMES
-	HLU
-	PATH_SUFFIXES
-	DebugAcademicEdition
-	Debug
-	HINTS
-	${_libsearchdirs})
-
-# fallback
-find_library(HLAPI_HLU_LIBRARY_DEBUG
-	NAMES
-	HLUD
-	PATH_SUFFIXES
-	DebugAcademicEdition
-	Debug
-	HINTS
-	${_libsearchdirs})
-
-select_library_configurations(HLAPI_HLU)
-
-if(OPENHAPTICS_NESTED_TARGETS OR NOT HLAPI_HLU_LIBRARY)
-	if(HLAPI_HLU_SOURCE_DIR AND NOT EXISTS "${HLAPI_HLU_SOURCE_DIR}/hlu.cpp")
-		unset(HLAPI_HLU_SOURCE_DIR)
-	endif()
-	find_path(HLAPI_HLU_SOURCE_DIR
-		NAMES
-		hlu.cpp
-		PATH_SUFFIXES
-		src
-		src/HLU
-		src/HLU/src
-		libsrc/HLU
-		HINTS
-		"${HLAPI_HLU_INCLUDE_DIR}/.."
-		"${HLAPI_HLU_INCLUDE_DIR}/../share/3DTouch")
-	list(APPEND _deps_check HLAPI_HLU_SOURCE_DIR)
-	if(HLAPI_HLU_SOURCE_DIR)
-		mark_as_advanced(HLAPI_HLU_SOURCE_DIR)
-		set(_nest_targets YES)
-		set(HLAPI_HLU_LIBRARY
-			"openhaptics_hlu_nested_target"
-			CACHE
-			STRING
-			"We will build the OpenHaptics HLU lib."
-			FORCE)
-		set(HLAPI_HLU_LIBRARIES ${HLAPI_HLU_LIBRARY})
-	endif()
-endif()
-
-###
-# Add dependencies: Libraries
-###
-set(HDAPI_LIBRARIES "${HDAPI_LIBRARY}" ${_deps_libs})
-
-if(HDAPI_HDU_LIBRARIES AND HDAPI_LIBRARIES)
-	list(APPEND HDAPI_HDU_LIBRARIES ${HDAPI_LIBRARIES})
-else()
-	set(HDAPI_HDU_LIBRARIES)
-endif()
-
-if(HLAPI_LIBRARY AND HDAPI_LIBRARIES)
-	set(HLAPI_LIBRARIES ${HLAPI_LIBRARY} ${HDAPI_LIBRARIES})
-else()
-	set(HLAPI_LIBRARIES)
-endif()
-
-if(HLAPI_HLU_LIBRARIES AND HLAPI_LIBRARIES)
-	list(APPEND HLAPI_HLU_LIBRARIES ${HLAPI_LIBRARIES})
-else()
-	set(HLAPI_HLU_LIBRARIES)
-endif()
-
-###
-# Add dependencies: Include dirs
-###
-if(HDAPI_INCLUDE_DIR)
-	set(HDAPI_INCLUDE_DIRS ${HDAPI_INCLUDE_DIR})
-
-	if(HDAPI_HDU_INCLUDE_DIR)
-		set(HDAPI_HDU_INCLUDE_DIRS
-			${HDAPI_INCLUDE_DIRS}
-			${HDAPI_HDU_INCLUDE_DIR})
-
-		if(HDAPI_HDU_INCLUDE_DIR)
-			set(HLAPI_INCLUDE_DIRS ${HDAPI_INCLUDE_DIRS} ${HLAPI_INCLUDE_DIR})
-
-			if(HLAPI_HLU_INCLUDE_DIR)
-				set(HLAPI_HLU_INCLUDE_DIRS
-					${HLAPI_INCLUDE_DIRS}
-					${HLAPI_HLU_INCLUDE_DIR})
-
-			endif()
-		endif()
-	endif()
-endif()
-
-# handle the QUIETLY and REQUIRED arguments and set xxx_FOUND to TRUE if
-# all listed variables are TRUE
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(OpenHaptics
-	DEFAULT_MSG
-	HDAPI_LIBRARY
-	HDAPI_INCLUDE_DIR
-	HDAPI_HDU_INCLUDE_DIR
-	HDAPI_HDU_LIBRARY
-	HLAPI_INCLUDE_DIR
-	HLAPI_LIBRARY
-	HLAPI_HLU_INCLUDE_DIR
-	HLAPI_HLU_LIBRARY
-	${_deps_check})
-
-if(OPENHAPTICS_FOUND)
-	# Recurse into the nested targets subdirectory if needed
-	if(_nest_targets)
-		get_filename_component(_moddir "${CMAKE_CURRENT_LIST_FILE}" PATH)
-		add_subdirectory("${_moddir}/nested_targets/OpenHaptics" "OpenHapticsNestedTargets")
-	endif()
-
-	set(OPENHAPTICS_LIBRARIES
-		${HDAPI_LIBRARY}
-		${HDAPI_HDU_LIBRARY}
-		${HLAPI_LIBRARY}
-		${HLAPI_HLU_LIBRARY})
-	set(OPENHAPTICS_LIBRARY_DIRS)
-	foreach(_lib
-		${_deps_check}
-		HDAPI_LIBRARY_RELEASE
-		HDAPI_LIBRARY_DEBUG
-		HDAPI_HDU_LIBRARY_RELEASE
-		HDAPI_HDU_LIBRARY_DEBUG
-		HLAPI_LIBRARY_RELEASE
-		HLAPI_LIBRARY_DEBUG
-		HLAPI_HLU_LIBRARY_RELEASE
-		HLAPI_HLU_LIBRARY_DEBUG)
-		get_filename_component(_libdir ${${_lib}} PATH)
-		list(APPEND OPENHAPTICS_LIBRARY_DIRS ${_libdir})
-	endforeach()
-
-	set(OPENHAPTICS_INCLUDE_DIRS
-		${HLAPI_HLU_INCLUDE_DIRS}
-		${HDAPI_HDU_INCLUDE_DIRS})
-
-	clean_directory_list(OPENHAPTICS_LIBRARY_DIRS)
-	clean_directory_list(OPENHAPTICS_INCLUDE_DIRS)
-
-	list(APPEND
-		OPENHAPTICS_RUNTIME_LIBRARY_DIRS
-		${OPENHAPTICS_LIBRARY_DIRS})
-
-	clean_library_list(OPENHAPTICS_LIBRARIES)
-
-	mark_as_advanced(OPENHAPTICS_ROOT_DIR)
-endif()
-
-mark_as_advanced(HDAPI_INCLUDE_DIR
-	HDAPI_LIBRARY_RELEASE
-	HDAPI_LIBRARY_DEBUG
-	HDAPI_HDU_INCLUDE_DIR
-	HDAPI_HDU_LIBRARY_RELEASE
-	HDAPI_HDU_LIBRARY_DEBUG
-	HLAPI_INCLUDE_DIR
-	HLAPI_LIBRARY_RELEASE
-	HLAPI_LIBRARY_DEBUG
-	HLAPI_HLU_INCLUDE_DIR
-	HLAPI_HLU_LIBRARY_RELEASE
-	HLAPI_HLU_LIBRARY_DEBUG)

src/vrpn/cmake/FindPerlModules.cmake

-# - try to find perl modules, passed as COMPONENTS
-#
-# Non-cache variable you might use in your CMakeLists.txt:
-#  PERLMODULES_FOUND
-#
-# Requires these CMake modules:
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#
-# Original Author:
-# 2012 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2012.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-if(NOT PERL_FOUND)
-	find_package(Perl QUIET)
-endif()
-
-set(_deps_check)
-if(PERL_FOUND)
-	foreach(module ${PerlModules_FIND_COMPONENTS})
-		string(REPLACE "::" "/" modfilename "${module}.pm")
-		string(REPLACE "::" "_" modvarname "PERLMODULES_${module}_MODULE")
-		string(TOUPPER "${modvarname}" modvarname)
-		list(APPEND _deps_check ${modvarname})
-		if(NOT ${modvarname})
-			if(NOT PerlModules_FIND_QUIETLY)
-				message(STATUS "Checking for perl module ${module}")
-			endif()
-			execute_process(COMMAND
-				"${PERL_EXECUTABLE}"
-				"-e"
-				"use ${module}; print \$INC{\"${modfilename}\"}"
-				RESULT_VARIABLE result_code
-				OUTPUT_VARIABLE filename
-				ERROR_VARIABLE error_info
-				OUTPUT_STRIP_TRAILING_WHITESPACE)
-			if(result_code EQUAL 0)
-				if(NOT PerlModules_FIND_QUIETLY)
-					message(STATUS
-						"Checking for perl module ${module} - found at ${filename}")
-				endif()
-				set(${modvarname}
-					"${filename}"
-					CACHE
-					FILEPATH
-					"Location found for module ${module}"
-					FORCE)
-				mark_as_advanced(${modvarname})
-			else()
-				if(NOT PerlModules_FIND_QUIETLY)
-					message(STATUS "Checking for perl module ${module} - failed")
-				endif()
-				set(${modvarname}
-					"NOTFOUND"
-					CACHE
-					FILEPATH
-					"No location found for module ${module}"
-					FORCE)
-				file(APPEND
-					${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
-					"Determining if the Perl module ${module} exists failed with the following error output:\n"
-					"${error_info}\n\n")
-			endif()
-		endif()
-	endforeach()
-endif()
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(PerlModules
-	DEFAULT_MSG
-	PERL_FOUND
-	${_deps_check})
-

src/vrpn/cmake/FindVRPN.cmake

-# - try to find VRPN library
-#
-# Cache Variables:
-#  VRPN_LIBRARY
-#  VRPN_SERVER_LIBRARY
-#  VRPN_INCLUDE_DIR
-#
-# Non-cache variables you might use in your CMakeLists.txt:
-#  VRPN_FOUND
-#  VRPN_SERVER_LIBRARIES - server libraries
-#  VRPN_LIBRARIES - client libraries
-#  VRPN_CLIENT_DEFINITIONS - definitions if you only use the client library
-#  VRPN_DEFINITIONS - Client-only definition if all we found was the client library.
-#  VRPN_INCLUDE_DIRS
-#
-# VRPN_ROOT_DIR is searched preferentially for these files
-#
-# Requires these CMake modules:
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#
-# Original Author:
-# 2009-2012 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2009-2012.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-set(VRPN_ROOT_DIR
-	"${VRPN_ROOT_DIR}"
-	CACHE
-	PATH
-	"Root directory to search for VRPN")
-
-if("${CMAKE_SIZEOF_VOID_P}" MATCHES "8")
-	set(_libsuffixes lib64 lib)
-
-	# 64-bit dir: only set on win64
-	file(TO_CMAKE_PATH "$ENV{ProgramW6432}" _progfiles)
-else()
-	set(_libsuffixes lib)
-	if(NOT "$ENV{ProgramFiles(x86)}" STREQUAL "")
-		# 32-bit dir: only set on win64
-		file(TO_CMAKE_PATH "$ENV{ProgramFiles(x86)}" _progfiles)
-	else()
-		# 32-bit dir on win32, useless to us on win64
-		file(TO_CMAKE_PATH "$ENV{ProgramFiles}" _progfiles)
-	endif()
-endif()
-
-###
-# Configure VRPN
-###
-
-find_path(VRPN_INCLUDE_DIR
-	NAMES
-	vrpn_Connection.h
-	PATH_SUFFIXES
-	include
-	include/vrpn
-	HINTS
-	"${VRPN_ROOT_DIR}"
-	PATHS
-	"${_progfiles}/VRPN"
-	C:/usr/local
-	/usr/local)
-
-find_library(VRPN_LIBRARY
-	NAMES
-	vrpn
-	PATH_SUFFIXES
-	${_libsuffixes}
-	HINTS
-	"${VRPN_ROOT_DIR}"
-	PATHS
-	"${_progfiles}/VRPN"
-	C:/usr/local
-	/usr/local)
-
-find_library(VRPN_SERVER_LIBRARY
-	NAMES
-	vrpnserver
-	PATH_SUFFIXES
-	${_libsuffixes}
-	HINTS
-	"${VRPN_ROOT_DIR}"
-	PATHS
-	"${_progfiles}/VRPN"
-	C:/usr/local
-	/usr/local)
-
-###
-# Dependencies
-###
-set(_deps_libs)
-set(_deps_includes)
-set(_deps_check)
-
-find_package(quatlib)
-list(APPEND _deps_libs ${QUATLIB_LIBRARIES})
-list(APPEND _deps_includes ${QUATLIB_INCLUDE_DIRS})
-list(APPEND _deps_check QUATLIB_FOUND)
-
-if(NOT WIN32)
-	find_package(Threads)
-	list(APPEND _deps_libs ${CMAKE_THREAD_LIBS_INIT})
-	list(APPEND _deps_check CMAKE_HAVE_THREADS_LIBRARY)
-endif()
-
-
-# handle the QUIETLY and REQUIRED arguments and set xxx_FOUND to TRUE if
-# all listed variables are TRUE
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(VRPN
-	DEFAULT_MSG
-	VRPN_LIBRARY
-	VRPN_INCLUDE_DIR
-	${_deps_check})
-
-if(VRPN_FOUND)
-	set(VRPN_INCLUDE_DIRS "${VRPN_INCLUDE_DIR}" ${_deps_includes})
-	set(VRPN_LIBRARIES "${VRPN_LIBRARY}" ${_deps_libs})
-	set(VRPN_SERVER_LIBRARIES "${VRPN_SERVER_LIBRARY}" ${_deps_libs})
-
-	if(VRPN_LIBRARY)
-		set(VRPN_CLIENT_DEFINITIONS -DVRPN_CLIENT_ONLY)
-	else()
-		unset(VRPN_CLIENT_DEFINITIONS)
-	endif()
-
-	if(VRPN_LIBRARY AND NOT VRPN_SERVER_LIBRARY)
-		set(VRPN_DEFINITIONS -DVRPN_CLIENT_ONLY)
-	else()
-		unset(VRPN_DEFINITIONS)
-	endif()
-
-	mark_as_advanced(VRPN_ROOT_DIR)
-endif()
-
-mark_as_advanced(VRPN_LIBRARY VRPN_SERVER_LIBRARY VRPN_INCLUDE_DIR)

src/vrpn/cmake/FindViewPoint.cmake

-# - try to find Arrington Research ViewPoint EyeTracker SDK
-#
-# Cache Variables: (probably not for direct use in your scripts)
-#  VIEWPOINT_INCLUDE_DIR
-#  VIEWPOINT_LIBRARY
-#  VIEWPOINT_RUNTIME_LIBRARY
-#
-# Non-cache variables you might use in your CMakeLists.txt:
-#  VIEWPOINT_FOUND
-#  VIEWPOINT_INCLUDE_DIRS
-#  VIEWPOINT_LIBRARIES
-#  VIEWPOINT_RUNTIME_LIBRARIES - aka the dll for installing
-#  VIEWPOINT_RUNTIME_LIBRARY_DIRS
-#
-# Requires these CMake modules:
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#
-# Original Author:
-# 2012 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2012.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-set(VIEWPOINT_ROOT_DIR
-	"${VIEWPOINT_ROOT_DIR}"
-	CACHE
-	PATH
-	"Directory to search for Arrington Research ViewPoint EyeTracker SDK")
-
-if(CMAKE_SIZEOF_VOID_P MATCHES "8")
-	set(_LIBSUFFIXES /lib64 /lib)
-else()
-	set(_LIBSUFFIXES /lib)
-endif()
-
-find_library(VIEWPOINT_LIBRARY
-	NAMES
-	VPX_InterApp
-	PATHS
-	"${VIEWPOINT_ROOT_DIR}"
-	PATH_SUFFIXES
-	"${_LIBSUFFIXES}")
-
-get_filename_component(_libdir "${VIEWPOINT_LIBRARY}" PATH)
-
-find_path(VIEWPOINT_INCLUDE_DIR
-	NAMES
-	vpx.h
-	HINTS
-	"${_libdir}"
-	PATHS
-	"${VIEWPOINT_ROOT_DIR}"
-	PATH_SUFFIXES
-	include/)
-
-set(_deps_check)
-if(WIN32)
-	find_file(VIEWPOINT_RUNTIME_LIBRARY
-		NAMES
-		VPX_InterApp.dll
-		HINTS
-		"${_libdir}")
-
-	set(VIEWPOINT_RUNTIME_LIBRARIES "${VIEWPOINT_RUNTIME_LIBRARY}")
-	get_filename_component(VIEWPOINT_RUNTIME_LIBRARY_DIRS
-		"${VIEWPOINT_RUNTIME_LIBRARY}"
-		PATH)
-	list(APPEND _deps_check VIEWPOINT_RUNTIME_LIBRARY)
-else()
-	get_filename_component(VIEWPOINT_RUNTIME_LIBRARY_DIRS
-		"${VIEWPOINT_LIBRARY}"
-		PATH)
-endif()
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(ViewPoint
-	DEFAULT_MSG
-	VIEWPOINT_LIBRARY
-	VIEWPOINT_INCLUDE_DIR
-	${_deps_check})
-
-if(VIEWPOINT_FOUND)
-	set(VIEWPOINT_LIBRARIES "${VIEWPOINT_LIBRARY}")
-	set(VIEWPOINT_INCLUDE_DIRS "${VIEWPOINT_INCLUDE_DIR}")
-	mark_as_advanced(VIEWPOINT_ROOT_DIR)
-endif()
-
-mark_as_advanced(VIEWPOINT_INCLUDE_DIR
-	VIEWPOINT_LIBRARY
-	VIEWPOINT_RUNTIME_LIBRARY)

src/vrpn/cmake/FindWiiUse.cmake

-# - try to find WiiUse library
-#
-# Cache Variables: (probably not for direct use in your scripts)
-#  WIIUSE_INCLUDE_DIR
-#  WIIUSE_LIBRARY
-#
-# Non-cache variables you might use in your CMakeLists.txt:
-#  WIIUSE_FOUND
-#  WIIUSE_INCLUDE_DIRS
-#  WIIUSE_LIBRARIES
-#  WIIUSE_RUNTIME_LIBRARIES - aka the dll for installing
-#  WIIUSE_RUNTIME_LIBRARY_DIRS
-#
-# Requires these CMake modules:
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#
-# Original Author:
-# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2009-2010.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-set(WIIUSE_ROOT_DIR
-	"${WIIUSE_ROOT_DIR}"
-	CACHE
-	PATH
-	"Directory to search for WiiUse")
-
-if(CMAKE_SIZEOF_VOID_P MATCHES "8")
-	set(_LIBSUFFIXES /lib64 /lib)
-else()
-	set(_LIBSUFFIXES /lib)
-endif()
-
-find_library(WIIUSE_LIBRARY
-	NAMES
-	wiiuse
-	PATHS
-	"${WIIUSE_ROOT_DIR}"
-	PATH_SUFFIXES
-	"${_LIBSUFFIXES}")
-
-get_filename_component(_libdir "${WIIUSE_LIBRARY}" PATH)
-
-find_path(WIIUSE_INCLUDE_DIR
-	NAMES
-	wiiuse.h
-	HINTS
-	"${_libdir}"
-	"${_libdir}/.."
-	PATHS
-	"${WIIUSE_ROOT_DIR}"
-	PATH_SUFFIXES
-	include/)
-
-set(_deps_check)
-if(WIN32)
-	find_file(WIIUSE_RUNTIME_LIBRARY
-		NAMES
-		wiiuse.dll
-		HINTS
-		"${_libdir}"
-		"${_libdir}/.."
-		PATH_SUFFIXES
-		bin)
-
-	set(WIIUSE_RUNTIME_LIBRARIES "${WIIUSE_RUNTIME_LIBRARY}")
-	get_filename_component(WIIUSE_RUNTIME_LIBRARY_DIRS
-		"${WIIUSE_RUNTIME_LIBRARY}"
-		PATH)
-	list(APPEND _deps_check WIIUSE_RUNTIME_LIBRARY)
-else()
-	set(WIIUSE_RUNTIME_LIBRARY "${WIIUSE_LIBRARY}")
-	set(WIIUSE_RUNTIME_LIBRARIES "${WIIUSE_RUNTIME_LIBRARY}")
-	get_filename_component(WIIUSE_RUNTIME_LIBRARY_DIRS
-		"${WIIUSE_LIBRARY}"
-		PATH)
-endif()
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(WiiUse
-	DEFAULT_MSG
-	WIIUSE_LIBRARY
-	WIIUSE_INCLUDE_DIR
-	${_deps_check})
-
-if(WIIUSE_FOUND)
-	set(WIIUSE_LIBRARIES "${WIIUSE_LIBRARY}")
-	set(WIIUSE_INCLUDE_DIRS "${WIIUSE_INCLUDE_DIR}")
-	mark_as_advanced(WIIUSE_ROOT_DIR)
-endif()
-
-mark_as_advanced(WIIUSE_INCLUDE_DIR
-	WIIUSE_LIBRARY
-	WIIUSE_RUNTIME_LIBRARY)

src/vrpn/cmake/FindWinHID.cmake

-# - try to find Windows HID support, part of the WDK/DDK
-#
-# Cache Variables: (probably not for direct use in your scripts)
-#  WINHID_INCLUDE_DIR
-#  WINHID_CRT_INCLUDE_DIR
-#  WINHID_LIBRARY
-#
-# Non-cache variables you might use in your CMakeLists.txt:
-#  WINHID_FOUND
-#  WINHID_INCLUDE_DIRS
-#  WINHID_LIBRARIES
-#
-# Requires these CMake modules:
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#  PrefixListGlob
-#  CleanDirectoryList
-#
-# Original Author:
-# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2009-2010.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-if(NOT WIN32)
-	find_package_handle_standard_args(WinHID
-		"Skipping search for Windows HID on non-Windows platform"
-		WIN32)
-	return()
-endif()
-if(MSVC)
-	if( (NOT WINHID_ROOT_DIR) AND (NOT ENV{DDKROOT} STREQUAL "") )
-		set(WINHID_ROOT_DIR "$ENV{DDKROOT}")
-	endif()
-endif()
-set(WINHID_ROOT_DIR
-	"${WINHID_ROOT_DIR}"
-	CACHE
-	PATH
-	"Directory to search")
-
-if(CMAKE_SIZEOF_VOID_P MATCHES "8")
-	set(_arch amd64) # what the architecture used to be called
-	set(_arch8 x64) # what the WDK for Win8+ calls this architecture
-else()
-	set(_arch i386) # what the architecture used to be called
-	set(_arch8 x86) # what the WDK for Win8+ calls this architecture
-endif()
-
-set(_deps_check)
-set(_need_crt_dir)
-if(MSVC)
-	include(PrefixListGlob)
-	include(CleanDirectoryList)
-	prefix_list_glob(_prefixed
-		"*/"
-		"$ENV{SYSTEMDRIVE}/WinDDK/"
-		"$ENV{ProgramFiles}/Windows Kits/"
-		"c:/WinDDK/")
-	clean_directory_list(_prefixed)
-	find_library(WINHID_LIBRARY
-		NAMES
-		hid
-		libhid
-		HINTS
-		"${WINHID_ROOT_DIR}"
-		${_prefixed}
-		PATH_SUFFIXES
-		"lib/w2k/${_arch}" # Win2k min requirement
-		"lib/wxp/${_arch}" # WinXP min requirement
-		"lib/wnet/${_arch}" # Win Server 2003 min requirement
-		"lib/wlh/${_arch}" # Win Vista ("Long Horn") min requirement
-		"lib/wlh/um/${_arch8}" # Win Vista ("Long Horn") min requirement
-		"lib/win7/${_arch}" # Win 7 min requirement
-		"lib/win7/um/${_arch8}" # Win 7 min requirement
-		"lib/win8/${_arch}" # Win 8 min requirement
-		"lib/win8/um/${_arch8}" # Win 8 min requirement
-		)
-	# Might want to look close to the library first for the includes.
-	if(WINHID_LIBRARY)
-		set(_prevdir)
-		get_filename_component(_basedir "${WINHID_LIBRARY}" PATH)
-		while(NOT IS_DIRECTORY "${_basedir}/lib" AND NOT (_basedir STREQUAL _prevdir))
-			set(_prevdir "${_basedir}")
-			get_filename_component(_basedir "${_basedir}/.." ABSOLUTE)
-		endwhile()
-	endif()
-
-	if(WINHID_LIBRARY AND EXISTS "${_basedir}/inc")
-		find_path(WINHID_CRT_INCLUDE_DIR # otherwise you get weird compile errors
-			NAMES
-			stdio.h
-			HINTS
-			"${_basedir}"
-			PATHS
-			"${WINHID_ROOT_DIR}"
-			PATH_SUFFIXES
-			inc/crt
-			NO_DEFAULT_PATH)
-		list(APPEND _deps_check WINHID_CRT_INCLUDE_DIR)
-		set(_need_crt_dir ON)
-	endif()
-
-	find_path(WINHID_INCLUDE_DIR
-		NAMES
-		hidsdi.h
-		HINTS
-		"${_basedir}"
-		PATHS
-		"${WINHID_ROOT_DIR}"
-		PATH_SUFFIXES
-		inc/ddk
-		inc/api
-		inc/w2k
-		inc/wxp
-		inc/wnet
-		include/shared)
-else()
-	find_library(WINHID_LIBRARY
-		NAMES
-		libhid
-		HINTS
-		"${WINHID_ROOT_DIR}"
-		/mingw
-		PATH_SUFFIXES
-		lib
-		lib/w32api)
-	find_path(WINHID_INCLUDE_DIR
-		NAMES
-		hidsdi.h
-		PATHS
-		"${WINHID_ROOT_DIR}"
-		/mingw
-		PATH_SUFFIXES
-		include/w32api/ddk
-		include/ddk
-		ddk)
-endif()
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(WinHID
-	DEFAULT_MSG
-	WINHID_LIBRARY
-	WINHID_INCLUDE_DIR
-	${_deps_check})
-
-if(WINHID_FOUND)
-	if(MSVC)
-		set(_winreq "Unknown")
-		if(WINHID_LIBRARY MATCHES "lib/w2k")
-			set(_winreq "Windows 2000")
-		elseif(WINHID_LIBRARY MATCHES "lib/wxp")
-			set(_winreq "Windows XP")
-		elseif(WINHID_LIBRARY MATCHES "lib/wnet")
-			set(_winreq "Windows Server 2003")
-		elseif(WINHID_LIBRARY MATCHES "lib/wlh")
-			set(_winreq "Windows Vista")
-		elseif(WINHID_LIBRARY MATCHES "lib/win7")
-			set(_winreq "Windows 7")
-		elseif(WINHID_LIBRARY MATCHES "lib/win8")
-			set(_winreq "Windows 8 (Possibly?)")
-		endif()
-		if(NOT "${WINHID_MIN_WINDOWS_VER}" STREQUAL "${_winreq}")
-			if(NOT WinHID_FIND_QUIETLY)
-				message(STATUS
-					"Linking against WINHID_LIBRARY will enforce this minimum version: ${_winreq}")
-			endif()
-			set(WINHID_MIN_WINDOWS_VER "${_winreq}" CACHE INTERNAL "" FORCE)
-		endif()
-	endif()
-	set(WINHID_LIBRARIES "${WINHID_LIBRARY}")
-	if(_need_crt_dir)
-		set(WINHID_INCLUDE_DIRS
-			"${WINHID_CRT_INCLUDE_DIR}"
-			"${WINHID_INCLUDE_DIR}")
-	else()
-		# Don't need that CRT include dir for WDK 8+
-		set(WINHID_INCLUDE_DIRS
-			"${WINHID_INCLUDE_DIR}")
-	endif()
-	mark_as_advanced(WINHID_ROOT_DIR)
-endif()
-
-mark_as_advanced(WINHID_INCLUDE_DIR
-	WINHID_CRT_INCLUDE_DIR
-	WINHID_LIBRARY)

src/vrpn/cmake/FindWindowsSDK.cmake

-# - Find the Windows SDK aka Platform SDK
-#
-# Relevant Wikipedia article: http://en.wikipedia.org/wiki/Microsoft_Windows_SDK
-#
-# Variables:
-#  WINDOWSSDK_FOUND - if any version of the windows or platform SDK was found that is usable with the current version of visual studio
-#  WINDOWSSDK_LATEST_DIR
-#  WINDOWSSDK_LATEST_NAME
-#  WINDOWSSDK_FOUND_PREFERENCE - if we found an entry indicating a "preferred" SDK listed for this visual studio version
-#  WINDOWSSDK_PREFERRED_DIR
-#  WINDOWSSDK_PREFERRED_NAME
-#
-#  WINDOWSSDK_DIRS - contains no duplicates, ordered most recent first.
-#  WINDOWSSDK_PREFERRED_FIRST_DIRS - contains no duplicates, ordered with preferred first, followed by the rest in descending recency
-#
-# Functions:
-#  windowssdk_name_lookup(<directory> <output variable>) - Find the name corresponding with the SDK directory you pass in, or
-#     NOTFOUND if not recognized. Your directory must be one of WINDOWSSDK_DIRS for this to work.
-#
-#  get_windowssdk_from_component(<file or dir> <output variable>) - Given a library or include dir,
-#     find the Windows SDK root dir corresponding to it, or NOTFOUND if unrecognized.
-#
-#  get_windowssdk_library_dirs(<directory> <output variable>) - Find the architecture-appropriate
-#     library directories corresponding to the SDK directory you pass in (or NOTFOUND if none)
-#
-#  get_windowssdk_include_dirs(<directory> <output variable>) - Find the
-#     include directories corresponding to the SDK directory you pass in (or NOTFOUND if none)
-#
-# Requires these CMake modules:
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#
-# Original Author:
-# 2012 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2012.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-set(_preferred_sdk_dirs)
-set(_win_sdk_dirs)
-set(_win_sdk_versanddirs)
-if(MSVC_VERSION GREATER 1310) # Newer than VS .NET/VS Toolkit 2003
-
-	# Environment variable for SDK dir
-	if(EXISTS "$ENV{WindowsSDKDir}" AND (NOT "$ENV{WindowsSDKDir}" STREQUAL ""))
-		message(STATUS "Got $ENV{WindowsSDKDir} - Windows/Platform SDK directories: ${_win_sdk_dirs}")
-		list(APPEND _preferred_sdk_dirs "$ENV{WindowsSDKDir}")
-	endif()
-
-	if(MSVC_VERSION LESS 1600)
-		# Per-user current Windows SDK for VS2005/2008
-		get_filename_component(_sdkdir
-			"[HKEY_CURRENT_USER\\Software\\Microsoft\\Microsoft SDKs\\Windows;CurrentInstallFolder]"
-			ABSOLUTE)
-		if(EXISTS "${_sdkdir}")
-			list(APPEND _preferred_sdk_dirs "${_sdkdir}")
-		endif()
-
-		# System-wide current Windows SDK for VS2005/2008
-		get_filename_component(_sdkdir
-			"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Microsoft SDKs\\Windows;CurrentInstallFolder]"
-			ABSOLUTE)
-		if(EXISTS "${_sdkdir}")
-			list(APPEND _preferred_sdk_dirs "${_sdkdir}")
-		endif()
-	endif()
-
-	if(MSVC_VERSION LESS 1700)
-		# VC 10 and older has broad target support
-		set(_winsdk_vistaonly)
-	else()
-		# VC 11 by default targets Vista and later only, so we can add a few more SDKs that (might?) only work on vista+
-		if("${CMAKE_VS_PLATFORM_TOOLSET}" MATCHES "_xp")
-			# This is the XP-compatible v110 toolset
-		elseif("${CMAKE_VS_PLATFORM_TOOLSET}" STREQUAL "v100")
-			# This is the VS2010 toolset
-		else()
-			if(NOT WINDOWSSDK_FOUND AND NOT WindowsSDK_FIND_QUIETLY)
-				message(STATUS "FindWindowsSDK: Detected Visual Studio 2012 or newer, not using the _xp toolset variant: including SDK versions that drop XP support in search!")
-			endif()
-			# These versions have no XP (and possibly Vista pre-SP1) support
-			set(_winsdk_vistaonly)
-			if(NOT MSVC_VERSION LESS 1800)
-				list(APPEND _winsdk_vistaonly
-					# Windows Software Development Kit (SDK) for Windows 8.1
-					# http://msdn.microsoft.com/en-gb/windows/desktop/bg162891
-					v8.1)
-			endif()
-			list(APPEND _winsdk_vistaonly
-				# Included in Visual Studio 2012
-				v8.0A
-
-				# Microsoft Windows SDK for Windows 8 and .NET Framework 4.5
-				# This is the first version to also include the DirectX SDK
-				# http://msdn.microsoft.com/en-US/windows/desktop/hh852363.aspx
-				v8.0
-
-				# Microsoft Windows SDK for Windows 7 and .NET Framework 4
-				# http://www.microsoft.com/downloads/en/details.aspx?FamilyID=6b6c21d2-2006-4afa-9702-529fa782d63b
-				v7.1
-				)
-		endif()
-	endif()
-	foreach(_winsdkver
-		${_winsdk_vistaonly}
-
-		# Included in Visual Studio 2013
-		# Includes the v120_xp toolset
-		v8.1A
-
-		# Included with VS 2012 Update 1 or later
-		# Introduces v110_xp toolset
-		v7.1A
-
-		# Included with VS 2010
-		v7.0A
-
-		# Windows SDK for Windows 7 and .NET Framework 3.5 SP1
-		# Works with VC9
-		#http://www.microsoft.com/en-us/download/details.aspx?id=18950
-		v7.0
-
-		# Two versions call themselves "v6.1":
-		# Older:
-		# Windows Vista Update & .NET 3.0 SDK
-		# http://www.microsoft.com/en-us/download/details.aspx?id=14477
-
-		# Newer:
-		# Windows Server 2008 & .NET 3.5 SDK
-		# may have broken VS9SP1? they recommend v7.0 instead, or a KB...
-		# http://www.microsoft.com/en-us/download/details.aspx?id=24826
-		v6.1
-
-		# Included in VS 2008
-		v6.0A
-
-		# Microsoft Windows Software Development Kit for Windows Vista and .NET Framework 3.0 Runtime Components
-		# http://blogs.msdn.com/b/stanley/archive/2006/11/08/microsoft-windows-software-development-kit-for-windows-vista-and-net-framework-3-0-runtime-components.aspx
-		v6.0)
-
-		get_filename_component(_sdkdir
-			"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Microsoft SDKs\\Windows\\${_winsdkver};InstallationFolder]"
-			ABSOLUTE)
-		if(EXISTS "${_sdkdir}")
-			list(APPEND _win_sdk_dirs "${_sdkdir}")
-			list(APPEND
-				_win_sdk_versanddirs
-				"Windows SDK ${_winsdkver}"
-				"${_sdkdir}")
-		endif()
-	endforeach()
-endif()
-if(MSVC_VERSION GREATER 1200)
-	foreach(_platformsdkinfo
-		"D2FF9F89-8AA2-4373-8A31-C838BF4DBBE1_Microsoft Platform SDK for Windows Server 2003 R2"
-		"8F9E5EF3-A9A5-491B-A889-C58EFFECE8B3_Microsoft Platform SDK for Windows Server 2003 SP1")
-		string(SUBSTRING "${_platformsdkinfo}" 0 36 _platformsdkguid)
-		string(SUBSTRING "${_platformsdkinfo}" 37 -1 _platformsdkname)
-		foreach(HIVE HKEY_LOCAL_MACHINE HKEY_CURRENT_USER)
-			get_filename_component(_sdkdir
-				"[${HIVE}\\SOFTWARE\\Microsoft\\MicrosoftSDK\\InstalledSDKs\\${_platformsdkguid};Install Dir]"
-				ABSOLUTE)
-			if(EXISTS "${_sdkdir}")
-				list(APPEND _win_sdk_dirs "${_sdkdir}")
-				list(APPEND _win_sdk_versanddirs "${_platformsdkname}" "${_sdkdir}")
-			endif()
-		endforeach()
-	endforeach()
-endif()
-
-set(_win_sdk_versanddirs
-	"${_win_sdk_versanddirs}"
-	CACHE
-	INTERNAL
-	"mapping between windows sdk version locations and names"
-	FORCE)
-
-function(windowssdk_name_lookup _dir _outvar)
-	list(FIND _win_sdk_versanddirs "${_dir}" _diridx)
-	math(EXPR _nameidx "${_diridx} - 1")
-	if(${_nameidx} GREATER -1)
-		list(GET _win_sdk_versanddirs ${_nameidx} _sdkname)
-	else()
-		set(_sdkname "NOTFOUND")
-	endif()
-	set(${_outvar} "${_sdkname}" PARENT_SCOPE)
-endfunction()
-
-if(_win_sdk_dirs)
-	# Remove duplicates
-	list(REMOVE_DUPLICATES _win_sdk_dirs)
-	list(GET _win_sdk_dirs 0 WINDOWSSDK_LATEST_DIR)
-	windowssdk_name_lookup("${WINDOWSSDK_LATEST_DIR}"
-		WINDOWSSDK_LATEST_NAME)
-	set(WINDOWSSDK_DIRS ${_win_sdk_dirs})
-endif()
-if(_preferred_sdk_dirs)
-	list(GET _preferred_sdk_dirs 0 WINDOWSSDK_PREFERRED_DIR)
-	windowssdk_name_lookup("${WINDOWSSDK_LATEST_DIR}"
-		WINDOWSSDK_PREFERRED_NAME)
-	set(WINDOWSSDK_PREFERRED_FIRST_DIRS
-		${_preferred_sdk_dirs}
-		${_win_sdk_dirs})
-	list(REMOVE_DUPLICATES WINDOWSSDK_PREFERRED_FIRST_DIRS)
-	set(WINDOWSSDK_FOUND_PREFERENCE ON)
-
-	# In case a preferred dir was found that isn't found otherwise
-	#set(WINDOWSSDK_DIRS ${WINDOWSSDK_DIRS} ${WINDOWSSDK_PREFERRED_FIRST_DIRS})
-	#list(REMOVE_DUPLICATES WINDOWSSDK_DIRS)
-else()
-	set(WINDOWSSDK_PREFERRED_DIR "${WINDOWSSDK_LATEST_DIR}")
-	set(WINDOWSSDK_PREFERRED_NAME "${WINDOWSSDK_LATEST_NAME}")
-	set(WINDOWSSDK_PREFERRED_FIRST_DIRS ${WINDOWSSDK_DIRS})
-	set(WINDOWSSDK_FOUND_PREFERENCE OFF)
-endif()
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(WindowsSDK
-	"No compatible version of the Windows SDK or Platform SDK found."
-	WINDOWSSDK_DIRS)
-
-if(WINDOWSSDK_FOUND)
-	if(NOT _winsdk_remembered_dirs STREQUAL WINDOWSSDK_DIRS)
-		set(_winsdk_remembered_dirs
-			"${WINDOWSSDK_DIRS}"
-			CACHE
-			INTERNAL
-			""
-			FORCE)
-		if(NOT WindowsSDK_FIND_QUIETLY)
-			foreach(_sdkdir ${WINDOWSSDK_DIRS})
-				windowssdk_name_lookup("${_sdkdir}" _sdkname)
-				message(STATUS " - Found ${_sdkname} at ${_sdkdir}")
-			endforeach()
-		endif()
-	endif()
-
-	# Internal: Architecture-appropriate library directory names.
-	if("${CMAKE_VS_PLATFORM_NAME}" STREQUAL "ARM")
-		set(_winsdk_archbare /arm) # what the architecture used to be called in oldest SDKs
-		set(_winsdk_arch arm) # what the architecture used to be called
-		set(_winsdk_arch8 arm) # what the WDK for Win8+ calls this architecture
-	else()
-		if(CMAKE_SIZEOF_VOID_P MATCHES "8")
-			set(_winsdk_archbare /x64) # what the architecture used to be called in oldest SDKs
-			set(_winsdk_arch amd64) # what the architecture used to be called
-			set(_winsdk_arch8 x64) # what the WDK for Win8+ calls this architecture
-		else()
-			set(_winsdk_archbare ) # what the architecture used to be called in oldest SDKs
-			set(_winsdk_arch i386) # what the architecture used to be called
-			set(_winsdk_arch8 x86) # what the WDK for Win8+ calls this architecture
-		endif()
-	endif()
-
-	function(get_windowssdk_from_component _component _var)
-		get_filename_component(_component "${_component}" ABSOLUTE)
-		file(TO_CMAKE_PATH "${_component}" _component)
-		foreach(_sdkdir ${WINDOWSSDK_DIRS})
-			get_filename_component(_sdkdir "${_sdkdir}" ABSOLUTE)
-			string(LENGTH "${_sdkdir}" _sdklen)
-			file(RELATIVE_PATH _rel "${_sdkdir}" "${_component}")
-			# If we don't have any "parent directory" items...
-			if(NOT "${_rel}" MATCHES "[.][.]")
-				set(${_var} "${_sdkdir}" PARENT_SCOPE)
-				return()
-			endif()
-		endforeach()
-		# Fail.
-		set(${_var} "NOTFOUND" PARENT_SCOPE)
-	endfunction()
-	function(get_windowssdk_library_dirs _winsdk_dir _var)
-		set(_result)
-		foreach(_suffix
-			"lib${_winsdk_archbare}" # SDKs like 7.1A
-			"lib/w2k/${_winsdk_arch}" # Win2k min requirement
-			"lib/wxp/${_winsdk_arch}" # WinXP min requirement
-			"lib/wnet/${_winsdk_arch}" # Win Server 2003 min requirement
-			"lib/wlh/${_winsdk_arch}" # Win Vista ("Long Horn") min requirement
-			"lib/wlh/um/${_winsdk_arch8}" # Win Vista ("Long Horn") min requirement
-			"lib/win7/${_winsdk_arch}" # Win 7 min requirement
-			"lib/win7/um/${_winsdk_arch8}" # Win 7 min requirement
-			"lib/win8/um/${_winsdk_arch8}" # Win 8 min requirement
-			"lib/win8/km/${_winsdk_arch8}" # Win 8 min requirement
-			"lib/winv6.3/km/${_winsdk_arch8}" # Win 8.1 min requirement
-			"lib/winv6.3/um/${_winsdk_arch8}" # Win 8.1 min requirement
-		)
-			# Check to see if a library actually exists here.
-			file(GLOB _libs "${_winsdk_dir}/${_suffix}/*.lib")
-			if(_libs)
-				list(APPEND _result "${_winsdk_dir}/${_suffix}")
-			endif()
-		endforeach()
-		if(NOT _result)
-			set(_result NOTFOUND)
-		endif()
-		set(${_var} ${_result} PARENT_SCOPE)
-	endfunction()
-	function(get_windowssdk_include_dirs _winsdk_dir _var)
-		set(_result)
-		foreach(_suffix
-			"Include"
-			"Include/shared"
-			"Include/um"
-			"Include/winrt"
-			"Include/km"
-			"Include/wdf"
-		)
-			# Check to see if a header file actually exists here.
-			file(GLOB _headers "${_winsdk_dir}/${_suffix}/*.h")
-			if(_headers)
-				list(APPEND _result "${_winsdk_dir}/${_suffix}")
-			endif()
-		endforeach()
-		if(NOT _result)
-			set(_result NOTFOUND)
-		endif()
-		set(${_var} ${_result} PARENT_SCOPE)
-	endfunction()
-endif()

src/vrpn/cmake/Findcppcheck.cmake

-# - try to find cppcheck tool
-#
-# Cache Variables:
-#  CPPCHECK_EXECUTABLE
-#
-# Non-cache variables you might use in your CMakeLists.txt:
-#  CPPCHECK_FOUND
-#  CPPCHECK_POSSIBLEERROR_ARG
-#  CPPCHECK_UNUSEDFUNC_ARG
-#  CPPCHECK_STYLE_ARG
-#  CPPCHECK_QUIET_ARG
-#  CPPCHECK_INCLUDEPATH_ARG
-#  CPPCHECK_FAIL_REGULAR_EXPRESSION
-#  CPPCHECK_WARN_REGULAR_EXPRESSION
-#  CPPCHECK_MARK_AS_ADVANCED - whether to mark our vars as advanced even
-#    if we don't find this program.
-#
-# Requires these CMake modules:
-#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
-#
-# Original Author:
-# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2009-2010.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-file(TO_CMAKE_PATH "${CPPCHECK_ROOT_DIR}" CPPCHECK_ROOT_DIR)
-set(CPPCHECK_ROOT_DIR
-	"${CPPCHECK_ROOT_DIR}"
-	CACHE
-	PATH
-	"Path to search for cppcheck")
-
-# cppcheck app bundles on Mac OS X are GUI, we want command line only
-set(_oldappbundlesetting ${CMAKE_FIND_APPBUNDLE})
-set(CMAKE_FIND_APPBUNDLE NEVER)
-
-if(CPPCHECK_EXECUTABLE AND NOT EXISTS "${CPPCHECK_EXECUTABLE}")
-	set(CPPCHECK_EXECUTABLE "notfound" CACHE PATH FORCE "")
-endif()
-
-# If we have a custom path, look there first.
-if(CPPCHECK_ROOT_DIR)
-	find_program(CPPCHECK_EXECUTABLE
-		NAMES
-		cppcheck
-		cli
-		PATHS
-		"${CPPCHECK_ROOT_DIR}"
-		PATH_SUFFIXES
-		cli
-		NO_DEFAULT_PATH)
-endif()
-
-find_program(CPPCHECK_EXECUTABLE NAMES cppcheck)
-
-# Restore original setting for appbundle finding
-set(CMAKE_FIND_APPBUNDLE ${_oldappbundlesetting})
-
-# Find out where our test file is
-get_filename_component(_cppcheckmoddir ${CMAKE_CURRENT_LIST_FILE} PATH)
-set(_cppcheckdummyfile "${_cppcheckmoddir}/Findcppcheck.cpp")
-if(NOT EXISTS "${_cppcheckdummyfile}")
-	message(FATAL_ERROR
-		"Missing file ${_cppcheckdummyfile} - should be alongside Findcppcheck.cmake, can be found at https://github.com/rpavlik/cmake-modules")
-endif()
-
-function(_cppcheck_test_arg _resultvar _arg)
-	if(NOT CPPCHECK_EXECUTABLE)
-		set(${_resultvar} NO)
-		return()
-	endif()
-	execute_process(COMMAND
-		"${CPPCHECK_EXECUTABLE}"
-		"${_arg}"
-		"--quiet"
-		"${_cppcheckdummyfile}"
-		RESULT_VARIABLE
-		_cppcheck_result
-		OUTPUT_QUIET
-		ERROR_QUIET)
-	if("${_cppcheck_result}" EQUAL 0)
-		set(${_resultvar} YES PARENT_SCOPE)
-	else()
-		set(${_resultvar} NO PARENT_SCOPE)
-	endif()
-endfunction()
-
-function(_cppcheck_set_arg_var _argvar _arg)
-	if("${${_argvar}}" STREQUAL "")
-		_cppcheck_test_arg(_cppcheck_arg "${_arg}")
-		if(_cppcheck_arg)
-			set(${_argvar} "${_arg}" PARENT_SCOPE)
-		endif()
-	endif()
-endfunction()
-
-if(CPPCHECK_EXECUTABLE)
-
-	# Check for the two types of command line arguments by just trying them
-	_cppcheck_set_arg_var(CPPCHECK_STYLE_ARG "--enable=style")
-	_cppcheck_set_arg_var(CPPCHECK_STYLE_ARG "--style")
-	if("${CPPCHECK_STYLE_ARG}" STREQUAL "--enable=style")
-
-		_cppcheck_set_arg_var(CPPCHECK_UNUSEDFUNC_ARG
-			"--enable=unusedFunction")
-		_cppcheck_set_arg_var(CPPCHECK_INFORMATION_ARG "--enable=information")
-		_cppcheck_set_arg_var(CPPCHECK_MISSINGINCLUDE_ARG
-			"--enable=missingInclude")
-		_cppcheck_set_arg_var(CPPCHECK_POSIX_ARG "--enable=posix")
-		_cppcheck_set_arg_var(CPPCHECK_POSSIBLEERROR_ARG
-			"--enable=possibleError")
-		_cppcheck_set_arg_var(CPPCHECK_POSSIBLEERROR_ARG "--enable=all")
-
-		if(MSVC)
-			set(CPPCHECK_TEMPLATE_ARG --template vs)
-			set(CPPCHECK_FAIL_REGULAR_EXPRESSION "[(]error[)]")
-			set(CPPCHECK_WARN_REGULAR_EXPRESSION "[(]style[)]")
-		elseif(CMAKE_COMPILER_IS_GNUCXX)
-			set(CPPCHECK_TEMPLATE_ARG --template gcc)
-			set(CPPCHECK_FAIL_REGULAR_EXPRESSION " error: ")
-			set(CPPCHECK_WARN_REGULAR_EXPRESSION " style: ")
-		else()
-			set(CPPCHECK_TEMPLATE_ARG --template gcc)
-			set(CPPCHECK_FAIL_REGULAR_EXPRESSION " error: ")
-			set(CPPCHECK_WARN_REGULAR_EXPRESSION " style: ")
-		endif()
-	elseif("${CPPCHECK_STYLE_ARG}" STREQUAL "--style")
-		# Old arguments
-		_cppcheck_set_arg_var(CPPCHECK_UNUSEDFUNC_ARG "--unused-functions")
-		_cppcheck_set_arg_var(CPPCHECK_POSSIBLEERROR_ARG "--all")
-		set(CPPCHECK_FAIL_REGULAR_EXPRESSION "error:")
-		set(CPPCHECK_WARN_REGULAR_EXPRESSION "[(]style[)]")
-	else()
-		# No idea - some other issue must be getting in the way
-		message(STATUS
-			"WARNING: Can't detect whether CPPCHECK wants new or old-style arguments!")
-	endif()
-
-	set(CPPCHECK_QUIET_ARG "--quiet")
-	set(CPPCHECK_INCLUDEPATH_ARG "-I")
-
-endif()
-
-set(CPPCHECK_ALL
-	"${CPPCHECK_EXECUTABLE} ${CPPCHECK_POSSIBLEERROR_ARG} ${CPPCHECK_UNUSEDFUNC_ARG} ${CPPCHECK_STYLE_ARG} ${CPPCHECK_QUIET_ARG} ${CPPCHECK_INCLUDEPATH_ARG} some/include/path")
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(cppcheck
-	DEFAULT_MSG
-	CPPCHECK_ALL
-	CPPCHECK_EXECUTABLE
-	CPPCHECK_POSSIBLEERROR_ARG
-	CPPCHECK_UNUSEDFUNC_ARG
-	CPPCHECK_STYLE_ARG
-	CPPCHECK_INCLUDEPATH_ARG
-	CPPCHECK_QUIET_ARG)
-
-if(CPPCHECK_FOUND OR CPPCHECK_MARK_AS_ADVANCED)
-	mark_as_advanced(CPPCHECK_ROOT_DIR)
-endif()
-
-mark_as_advanced(CPPCHECK_EXECUTABLE)